Temporary addition of fixed libqb #720910

2 files changed, 64 insertions, 0 deletions

diff --git a/sys-cluster/libqb/Manifest b/sys-cluster/libqb/Manifest
new file mode 100644
index 0000000..a45a3cd
--- /dev/null
+++ b/sys-cluster/libqb/Manifest
@@ -0,0 +1,2 @@
+DIST libqb-1.9.1.tar.gz 233250 BLAKE2B a2e584bd2448aa1f051cfc69dd5b14bbd4a6ec6ebe6c163df43cf94888de7780f46e41ebadd63f0f3bc31ae04bd5e3581056dfb6543438b4767a97ab899572f8 SHA512 307c23ce8c306b1ff337f6ef0bbb42eee42f7f9adf79f5884ad066c5fe5162eaf394fcea11175fb2180f7c9ba4ec8ff54a218931d52cd3d40fcfd094887a03dc
+EBUILD libqb-1.9.1.ebuild 1324 BLAKE2B c8d226238ef2a15b55e7796bc66dbd168bf538e6bd2ea00558bcb92073a2b3932959d09ceb0a6637e5eb6c5ba6cd8657be1a0d2636d1e54537fb7563a287a042 SHA512 d8b337bd282416ba5786035b22d89d652fe088350e7e44718e1ff3de6f452343f77b095516cc307c14fce4e8a1f687fc029e4099b0aa3c0c6e398b94cfa701f1
diff --git a/sys-cluster/libqb/libqb-1.9.1.ebuild b/sys-cluster/libqb/libqb-1.9.1.ebuild
new file mode 100644
index 0000000..6ae629b
--- /dev/null
+++ b/sys-cluster/libqb/libqb-1.9.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Library providing high performance logging, tracing, ipc, and poll"
+HOMEPAGE="https://github.com/ClusterLabs/libqb"
+
+# Avoiding release tarball due to https://github.com/ClusterLabs/libqb/issues/375
+# Please re-add ChangeLog to DOCS when switching back
+SRC_URI="https://github.com/ClusterLabs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/20"
+KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="debug doc examples systemd test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-libs/glib:2"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	test? ( dev-libs/check )
+	doc? ( app-doc/doxygen[dot] )"
+
+DOCS=( README.markdown )
+
+src_prepare() {
+	default
+
+	# Skip installation of text documents without value
+	sed -e '/dist_doc_DATA/d' -i Makefile.am || die
+
+	# Do not append version suffix "-yank"
+	sed 's|1-yank|1|' -i configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable systemd systemd-journal) \
+		$(use_enable debug)
+}
+
+src_compile() {
+	default
+	use doc && emake doxygen
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+
+	use doc && HTML_DOCS=("docs/html/.")
+	einstalldocs
+}