Add a version transmission with the corrected checksums

2 files changed, 92 insertions, 0 deletions

diff --git a/net-p2p/transmission/Manifest b/net-p2p/transmission/Manifest
new file mode 100644
index 0000000..4ac7536
--- /dev/null
+++ b/net-p2p/transmission/Manifest
@@ -0,0 +1,2 @@
+DIST transmission-2.00.tar.bz2 4259539 RMD160 ef8d4ee09c0f01de4ebe37204c276bde75927971 SHA1 19d852e64c07f7f7c0466dcb6d09dd20698bbfce SHA256 370abe5058f378382826511a8611e20a98f81a726e07ce74e4040e9b9fb5f0e7
+EBUILD transmission-2.00.ebuild 2276 RMD160 6c7373661552f410ad9212607918c08fd6aa15a4 SHA1 93045e5e6f01f7bb6e2cb3444417db7ed12e5fac SHA256 1d7afbb8f59cc5d609ea3b9030c2eee1d429deea2dce59656eedff61686be5e7
diff --git a/net-p2p/transmission/transmission-2.00.ebuild b/net-p2p/transmission/transmission-2.00.ebuild
new file mode 100644
index 0000000..635b813
--- /dev/null
+++ b/net-p2p/transmission/transmission-2.00.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-2.00.ebuild,v 1.4 2010/06/18 10:25:09 pva Exp $
+
+EAPI=2
+inherit eutils fdo-mime gnome2-utils qt4-r2
+
+DESCRIPTION="A Fast, Easy and Free BitTorrent client"
+HOMEPAGE="http://www.transmissionbt.com/"
+SRC_URI="http://download.transmissionbt.com/${PN}/files/${P}.tar.bz2"
+
+LICENSE="MIT GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+IUSE="gnome gtk libnotify sound qt4"
+
+RDEPEND="
+	sys-libs/zlib
+	>=dev-libs/libevent-1.4.11
+	<dev-libs/libevent-2
+	>=dev-libs/openssl-0.9.4
+	|| ( >=net-misc/curl-7.16.3[ssl]
+		>=net-misc/curl-7.16.3[gnutls] )
+	gtk? ( >=dev-libs/glib-2.15.5:2
+		>=x11-libs/gtk+-2.12:2
+		>=dev-libs/dbus-glib-0.70
+		gnome? ( >=gnome-base/gconf-2.20.0 )
+		libnotify? ( >=x11-libs/libnotify-0.4.3 )
+		sound? ( >=media-libs/libcanberra-0.10 ) )
+	qt4? ( x11-libs/qt-gui:4 )"
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2.2.6b
+	sys-devel/gettext
+	>=dev-util/intltool-0.40
+	dev-util/pkgconfig
+	sys-apps/sed"
+
+src_prepare() {
+	sed -i -e 's:-ggdb3::g' configure || die
+}
+
+src_configure() {
+	# cli and daemon doesn't have external deps and are enabled by default
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable gtk) \
+		$(use gtk && use_enable libnotify) \
+		$(use gtk && use_enable sound libcanberra) \
+		$(use gtk && use_enable gnome gconf2)
+
+	use qt4 && cd qt && eqmake4 qtr.pro
+}
+
+src_compile() {
+	emake || die
+	use qt4 && cd qt && { emake || die; }
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS NEWS qt/README.txt
+	rm -f "${D}"/usr/share/${PN}/web/LICENSE
+
+	# these are likely outdated for 1.83
+	newinitd "${FILESDIR}"/${PN}-daemon.initd.2 ${PN}-daemon || die
+	newconfd "${FILESDIR}"/${PN}-daemon.confd.1 ${PN}-daemon || die
+
+	if use qt4; then
+		cd qt
+		emake INSTALL_ROOT="${D}/usr" install || die
+		make_desktop_entry qtr "Transmission Qt BitTorrent Client" ${PN} \
+			"Network;FileTransfer;P2P;Qt"
+		use gtk || doicon qt/icons/transmission.png
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}