blob: 68420d495473d253475cb9ed53c3a5c1629f41c8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
|
// **********************************************************************
//
// Copyright (c) 2003-2017 ZeroC, Inc. All rights reserved.
//
// This copy of Ice is licensed to you under the terms described in the
// ICE_LICENSE file included in this distribution.
//
// **********************************************************************
#include <Ice/ObjectFactory.h>
#import <ValueFactoryI.h>
#import <LocalObjectI.h>
#import <StreamI.h>
#import <Util.h>
#import <objc/Ice/ObjectFactory.h>
#import <objc/Ice/SlicedData.h>
#import <objc/runtime.h>
namespace IceObjC
{
class UnknownSlicedValueFactoryI : public Ice::ValueFactory
{
public:
virtual Ice::ObjectPtr
create(const std::string&)
{
ICEUnknownSlicedValue* obj = [[ICEUnknownSlicedValue alloc] init];
Ice::ObjectPtr o = [ICEInputStream createObjectReader:obj];
[obj release];
return o;
}
};
class ValueFactoryI : public Ice::ValueFactory
{
public:
ValueFactoryI(NSDictionary* factories, NSDictionary* prefixTable) :
_factories(factories), _prefixTable(prefixTable)
{
CFRetain(_factories);
CFRetain(_prefixTable);
}
~ValueFactoryI()
{
CFRelease(_factories);
CFRelease(_prefixTable);
}
virtual Ice::ObjectPtr
create(const std::string& type)
{
NSString* sliceId = [[NSString alloc] initWithUTF8String:type.c_str()];
NSException* ex = nil;
@try
{
ICEValueFactory factory = nil;
@synchronized(_factories)
{
factory = [_factories objectForKey:sliceId];
if(factory == nil)
{
factory = [_factories objectForKey:@""];
}
}
ICEObject* obj = nil;
if(factory != nil)
{
obj = factory(sliceId);
}
if(obj == nil)
{
std::string tId = toObjCSliceId(type, _prefixTable);
Class c = objc_lookUpClass(tId.c_str());
if(c == nil)
{
return 0; // No value factory.
}
if([c isSubclassOfClass:[ICEObject class]])
{
obj = (ICEObject*)[[c alloc] init];
}
}
Ice::ObjectPtr o;
if(obj != nil)
{
o = [ICEInputStream createObjectReader:obj];
[obj release];
}
return o;
}
@catch(id exc)
{
ex = exc;
}
@finally
{
[sliceId release];
}
if(ex != nil)
{
rethrowCxxException(ex);
}
return nil; // Keep the compiler happy.
}
private:
NSDictionary* _factories;
NSDictionary* _prefixTable;
};
}
@implementation ICEValueFactoryManager
-(id) init:(Ice::Communicator*)com prefixTable:(NSDictionary*)prefixTable
{
self = [super init];
if(!self)
{
return nil;
}
valueFactories_ = [[NSMutableDictionary alloc] init];
com->getValueFactoryManager()->add(new IceObjC::UnknownSlicedValueFactoryI, "::Ice::Object");
com->getValueFactoryManager()->add(new IceObjC::ValueFactoryI(valueFactories_, prefixTable), "");
return self;
}
-(void) dealloc
{
[valueFactories_ release];
[super dealloc];
}
-(void) add:(ICEValueFactory)factory sliceId:(NSString*)sliceId
{
@synchronized(valueFactories_)
{
[valueFactories_ setObject:ICE_AUTORELEASE([factory copy]) forKey:sliceId];
}
}
-(ICEValueFactory) find:(NSString*)sliceId
{
@synchronized(valueFactories_)
{
return [valueFactories_ objectForKey:sliceId];
}
return nil; // Keep the compiler happy.
}
@end
|
