1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
|
// **********************************************************************
//
// Copyright (c) 2003-2015 ZeroC, Inc. All rights reserved.
//
// This copy of Ice is licensed to you under the terms described in the
// ICE_LICENSE file included in this distribution.
//
// **********************************************************************
#import <BatchRequestInterceptorI.h>
#import <Util.h>
#import <ProxyI.h>
#include <Block.h>
@interface ICEBatchRequest : NSObject<ICEBatchRequest>
{
const Ice::BatchRequest* cxxRequest_;
}
-(void) reset:(const Ice::BatchRequest*)call;
@end
namespace
{
class BatchRequestInterceptorI : public Ice::BatchRequestInterceptor
{
public:
// We must explicitely retain/release so that the garbage
// collector does not trash the dispatcher.
BatchRequestInterceptorI(void(^interceptor)(id<ICEBatchRequest>, int, int)) :
_interceptor(Block_copy(interceptor)), _request([[ICEBatchRequest alloc] init])
{
}
virtual ~BatchRequestInterceptorI()
{
Block_release(_interceptor);
[_request release];
}
virtual void
enqueue(const Ice::BatchRequest& request, int count, int size)
{
NSException* ex = nil;
@autoreleasepool
{
@try
{
[_request reset:&request];
_interceptor(_request, count, size);
}
@catch(id e)
{
ex = [e retain];
}
}
if(ex != nil)
{
rethrowCxxException(ex, true); // True = release the exception.
}
}
private:
void(^_interceptor)(id<ICEBatchRequest>, int, int);
ICEBatchRequest* _request;
};
typedef IceUtil::Handle<BatchRequestInterceptorI> BatchRequestInterceptorIPtr;
}
@implementation ICEBatchRequestInterceptor
+(Ice::BatchRequestInterceptor*)
batchRequestInterceptorWithBatchRequestInterceptor:(void(^)(id<ICEBatchRequest>, int, int))interceptor
{
return new BatchRequestInterceptorI(interceptor);
}
@end
@implementation ICEBatchRequest
-(void) reset:(const Ice::BatchRequest*)request
{
cxxRequest_ = request;
}
-(void) enqueue
{
cppCall(^ { cxxRequest_->enqueue(); });
}
-(int) getSize
{
return cxxRequest_->getSize();
}
-(NSString*) getOperation
{
return [toNSString(cxxRequest_->getOperation()) autorelease];
}
-(id<ICEObjectPrx>) getProxy
{
return [ICEObjectPrx objectPrxWithObjectPrx__:cxxRequest_->getProxy()];
}
@end
|
