From 7c1e9b25fa4062a69ea00c20cdbcc745d1b82659 Mon Sep 17 00:00:00 2001
From: Dan Goodliffe <dan@randomdan.homeip.net>
Date: Thu, 5 Jan 2023 19:45:36 +0000
Subject: Add rendering support for spot lights

---
 gfx/gl/shaders/spotLight.fs | 34 ++++++++++++++++++++++++
 gfx/gl/shaders/spotLight.gs | 63 +++++++++++++++++++++++++++++++++++++++++++++
 gfx/gl/shaders/spotLight.vs | 23 +++++++++++++++++
 3 files changed, 120 insertions(+)
 create mode 100644 gfx/gl/shaders/spotLight.fs
 create mode 100644 gfx/gl/shaders/spotLight.gs
 create mode 100644 gfx/gl/shaders/spotLight.vs

(limited to 'gfx/gl/shaders')

diff --git a/gfx/gl/shaders/spotLight.fs b/gfx/gl/shaders/spotLight.fs
new file mode 100644
index 0000000..add86fd
--- /dev/null
+++ b/gfx/gl/shaders/spotLight.fs
@@ -0,0 +1,34 @@
+#version 330 core
+#extension GL_ARB_shading_language_420pack : enable
+
+out vec3 FragColor;
+
+layout(binding = 0) uniform sampler2D gPosition;
+layout(binding = 1) uniform sampler2D gNormal;
+uniform ivec4 viewPort;
+uniform vec3 colour;
+uniform float kq;
+in vec4 geo_centre;
+in vec4 geo_direction;
+
+void
+main()
+{
+	const vec2 texCoord = gl_FragCoord.xy / viewPort.zw;
+	const vec3 position = texture(gPosition, texCoord).xyz;
+	const vec3 lightv = position - geo_centre.xyz;
+	const float lightDist = length(lightv);
+	if (lightDist > geo_centre.w) {
+		discard;
+	}
+	const vec3 lightDirection = normalize(lightv);
+	if (dot(lightDirection, geo_direction.xyz) < geo_direction.w) {
+		discard;
+	}
+	const vec3 normal = texture(gNormal, texCoord).xyz;
+	const float normalDot = dot(-lightDirection, normal);
+	if (normalDot < 0) {
+		discard;
+	}
+	FragColor = (colour * normalDot) / (1 + (kq * pow(lightDist, 2)));
+}
diff --git a/gfx/gl/shaders/spotLight.gs b/gfx/gl/shaders/spotLight.gs
new file mode 100644
index 0000000..ad65675
--- /dev/null
+++ b/gfx/gl/shaders/spotLight.gs
@@ -0,0 +1,63 @@
+#version 330 core
+#extension GL_ARB_enhanced_layouts : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+const vec3[] pyramid = vec3[]( // four-sided
+		vec3(0, 0, 0), // Apex
+		vec3(-1, 1, 1), // Back-left
+		vec3(-1, -1, 1), // Front-left
+		vec3(1, 1, 1), // Back-right
+		vec3(1, -1, 1) // Front-right
+);
+uniform mat4 viewProjection;
+uniform float arc;
+
+in vec3 position[];
+in vec3 direction[];
+in float size[];
+in float cosarc[];
+layout(points) in;
+
+layout(triangle_strip, max_vertices = 8) out;
+out vec4 geo_centre;
+out vec4 geo_direction;
+
+vec3
+perp(vec3 a)
+{
+	return normalize(a.x != 0  ? vec3((a.y + a.z) / -a.x, 1, 1)
+					: a.y != 0 ? vec3(1, (a.x + a.z) / -a.y, 1)
+							   : vec3(1, 1, (a.x + a.y) / -a.z));
+}
+
+void
+doVertex(vec4 ndcpos)
+{
+	gl_Position = ndcpos;
+	geo_centre = vec4(position[0], size[0]);
+	geo_direction = vec4(direction[0], cosarc[0]);
+	EmitVertex();
+}
+
+void
+main()
+{
+	const float base = size[0] * tan(arc / 2);
+	const vec3 offx = perp(direction[0]);
+	const vec3 offy = cross(direction[0], offx);
+	vec4 out_py[pyramid.length()];
+	for (int i = 0; i < pyramid.length(); ++i) {
+		const vec3 p = pyramid[i];
+		const vec3 edge = (offx * base * p.x) + (offy * base * p.y) + (direction[0] * size[0] * p.z);
+		out_py[i] = viewProjection * (gl_in[0].gl_Position + vec4(edge, 1));
+	}
+	doVertex(out_py[3]);
+	doVertex(out_py[0]);
+	doVertex(out_py[1]);
+	doVertex(out_py[2]);
+	doVertex(out_py[3]);
+	doVertex(out_py[4]);
+	doVertex(out_py[0]);
+	doVertex(out_py[2]);
+	EndPrimitive();
+}
diff --git a/gfx/gl/shaders/spotLight.vs b/gfx/gl/shaders/spotLight.vs
new file mode 100644
index 0000000..e648553
--- /dev/null
+++ b/gfx/gl/shaders/spotLight.vs
@@ -0,0 +1,23 @@
+#version 330 core
+
+layout(location = 0) in vec3 v_position;
+layout(location = 1) in vec3 v_direction;
+
+uniform vec3 colour;
+uniform float kq;
+uniform float arc;
+
+out vec3 position;
+out vec3 direction;
+out float size;
+out float cosarc;
+
+void
+main()
+{
+	position = v_position;
+	direction = normalize(v_direction);
+	size = (8 * sqrt(max(max(colour.r, colour.g), colour.b))) / sqrt(kq);
+	cosarc = cos(arc / 2);
+	gl_Position = vec4(position, 0);
+}
-- 
cgit v1.2.3