Merge remote-tracking branch 'origin/instanced-networks'

6 files changed, 177 insertions, 0 deletions

diff --git a/gfx/gl/shaders/network.fs b/gfx/gl/shaders/network.fs
new file mode 100644
index 0000000..4e347b4
--- /dev/null
+++ b/gfx/gl/shaders/network.fs
@@ -0,0 +1,17 @@
+#version 330 core
+#extension GL_ARB_shading_language_420pack : enable
+
+include(`materialOut.glsl')
+in vec3 rposition;
+in vec2 texCoord;
+
+layout(binding = 0) uniform sampler2D texture0;
+uniform ivec3 viewPoint;
+
+void
+main()
+{
+	gPosition = ivec4(viewPoint + rposition, 1);
+	gNormal = vec4(0, 0, 1, 1);
+	gAlbedoSpec = texture(texture0, texCoord);
+}
diff --git a/gfx/gl/shaders/networkCommon.glsl b/gfx/gl/shaders/networkCommon.glsl
new file mode 100644
index 0000000..0bc3c1c
--- /dev/null
+++ b/gfx/gl/shaders/networkCommon.glsl
@@ -0,0 +1,43 @@
+uniform vec3[10] profile;
+uniform float[10] texturePos;
+uniform uint profileLength;
+
+uniform mat4 viewProjection;
+uniform ivec3 viewPoint;
+
+uniform float clipDistance = 5000000;
+uniform float flatDistance = 1000000;
+
+out vec2 texCoord;
+out vec3 rposition;
+
+float
+segDist(const ivec3 a, const ivec3 b)
+{
+	return min(distance(viewPoint, a), distance(viewPoint, b));
+}
+
+ifelse(
+		TYPE, .gs,
+		// Begin: Geometry shader only function
+		void doVertex(const ivec3 end, const uint v, const float texY, const mat2 rot) {
+			ivec3 vpos = end + ivec3(rot * profile[v].xy, profile[v].z);
+			rposition = vpos - viewPoint;
+			gl_Position = viewProjection * vec4(rposition, 1);
+			texCoord = vec2(texturePos[v], texY);
+			EmitVertex();
+		}
+
+		void doSeg(const float dist, const ivec3 apos, const ivec3 bpos, const float atexY, const float btexY,
+				const mat2 arot, const mat2 brot) {
+			if (dist < clipDistance) {
+				uint vstep = (dist < flatDistance) ? 1u : profileLength - 1u;
+				for (uint v = 0u; v < profileLength; v += vstep) {
+					doVertex(bpos, v, btexY, brot);
+					doVertex(apos, v, atexY, arot);
+				}
+				EndPrimitive();
+			}
+		}
+		// End: Geometry shader only function
+)
diff --git a/gfx/gl/shaders/networkCurve.gs b/gfx/gl/shaders/networkCurve.gs
new file mode 100644
index 0000000..7cb6c42
--- /dev/null
+++ b/gfx/gl/shaders/networkCurve.gs
@@ -0,0 +1,47 @@
+#version 330 core
+
+flat in ivec3 apos[];
+flat in ivec3 bpos[];
+flat in ivec3 cpos[];
+flat in float reps[];
+flat in float aangle[];
+flat in float bangle[];
+flat in float radius[];
+
+layout(points) in;
+layout(triangle_strip, max_vertices = GL_MAX_GEOMETRY_OUTPUT_VERTICES) out;
+
+const mat2 rot = mat2(1);
+
+include(`networkCommon.glsl')
+
+mat2
+getRot(float angle)
+{
+	return mat2(cos(angle), sin(angle), -sin(angle), cos(angle));
+}
+
+void
+main()
+{
+	float segs = clamp(
+			round(reps[0] * radius[0] / 1000), 4, floor(uint(GL_MAX_GEOMETRY_OUTPUT_VERTICES) / (profileLength * 2u)));
+	vec3 arcstep = vec3((bangle[0] - aangle[0]), // angle
+						   reps[0], // texture
+						   (bpos[0].z - apos[0].z)) // height
+			/ segs;
+
+	ivec3 prevPos = apos[0];
+	mat2 prevRot = getRot(aangle[0]);
+	float prevTex = 0;
+	for (vec3 arc = arcstep; arc.y < reps[0] - 0.01; arc += arcstep) {
+		mat2 rot = getRot(arc.x + aangle[0]);
+		ivec3 pos = cpos[0] + ivec3(rot * vec2(radius[0], 0), arc.z);
+		float tex = arc.y;
+		doSeg(segDist(prevPos, pos), pos, prevPos, tex, prevTex, rot, prevRot);
+		prevPos = pos;
+		prevRot = rot;
+		prevTex = tex;
+	}
+	doSeg(segDist(prevPos, bpos[0]), bpos[0], prevPos, reps[0], prevTex, getRot(bangle[0]), prevRot);
+}
diff --git a/gfx/gl/shaders/networkCurve.vs b/gfx/gl/shaders/networkCurve.vs
new file mode 100644
index 0000000..f51bb87
--- /dev/null
+++ b/gfx/gl/shaders/networkCurve.vs
@@ -0,0 +1,29 @@
+#version 330 core
+
+layout(location = 0) in ivec3 v_apos;
+layout(location = 1) in ivec3 v_bpos;
+layout(location = 2) in ivec3 v_centre;
+layout(location = 3) in float v_reps;
+layout(location = 4) in float v_aangle;
+layout(location = 5) in float v_bangle;
+layout(location = 6) in float v_radius;
+
+flat out ivec3 apos;
+flat out ivec3 bpos;
+flat out ivec3 cpos;
+flat out float reps;
+flat out float aangle;
+flat out float bangle;
+flat out float radius;
+
+void
+main()
+{
+	apos = v_apos;
+	bpos = v_bpos;
+	cpos = v_centre;
+	reps = v_reps;
+	aangle = v_aangle;
+	bangle = v_bangle;
+	radius = v_radius;
+}
diff --git a/gfx/gl/shaders/networkStraight.gs b/gfx/gl/shaders/networkStraight.gs
new file mode 100644
index 0000000..51df5fb
--- /dev/null
+++ b/gfx/gl/shaders/networkStraight.gs
@@ -0,0 +1,17 @@
+#version 330 core
+
+flat in ivec3 apos[];
+flat in ivec3 bpos[];
+flat in mat2 rot[];
+flat in float reps[];
+flat in float dist[];
+
+layout(points) in;
+layout(triangle_strip, max_vertices = 10) out;
+include(`networkCommon.glsl')
+
+void
+main()
+{
+	doSeg(dist[0], apos[0], bpos[0], 0.f, reps[0], rot[0], rot[0]);
+}
diff --git a/gfx/gl/shaders/networkStraight.vs b/gfx/gl/shaders/networkStraight.vs
new file mode 100644
index 0000000..55f9c4f
--- /dev/null
+++ b/gfx/gl/shaders/networkStraight.vs
@@ -0,0 +1,24 @@
+#version 330 core
+
+layout(location = 0) in ivec3 v_apos;
+layout(location = 1) in ivec3 v_bpos;
+layout(location = 2) in mat2 v_rot;
+layout(location = 4) in float v_reps;
+
+flat out ivec3 apos;
+flat out ivec3 bpos;
+flat out mat2 rot;
+flat out float reps;
+flat out float dist;
+
+include(`networkCommon.glsl')
+
+void
+main()
+{
+	apos = v_apos;
+	bpos = v_bpos;
+	rot = v_rot;
+	reps = v_reps;
+	dist = segDist(v_apos, v_bpos);
+}